up_key = keyboard_check_pressed(vk_up);
down_key = keyboard_check_pressed(vk_down);
accept_key = keyboard_check_pressed(vk_enter);

// Atjaunināt opciju garumu pašreizējam izvēlnes līmenim
op_length = array_length(option[menu_level]);

// Navigēt caur opcijām
pos += down_key - up_key;
if pos >= op_length { pos = 0; }
if pos < 0 { pos = op_length - 1; }

// Apstrādāt opcijas izvēli
if accept_key {
    var _sml = menu_level;

    switch (menu_level) {
        case 0: // Pauzes izvēlne
            switch (pos) {
                case 0: keyboard_key_press(ord("P")); break; // Atsākt spēli
                case 1:
                    // Šeit izsauciet save_player_to_firebase funkciju
					save_game();
                    //save_player_to_firebase(oPlayer.x, oPlayer.y, global.player_name, global.elapsed_time);
                    break; // Saglabāt spēli
                case 2: menu_level = 1; break; // Iestatījumi
                case 3: room_goto(rmTitle_Menu); break; // Galvenā izvēlne
            }
            break;

        case 1: // Iestatījumu izvēlne
            switch (pos) {
                case 0: menu_level = 2; break; // Loga izmēra apakšizvēlne
                case 1: menu_level = 3; break; // Vadības apakšizvēlne
                case 2: menu_level = 4; break; // Mērķa apakšizvēlne
                case 3: menu_level = 0; break; // Atpakaļ uz pauzes izvēlni
            }
            break;

        case 2: // Loga izmēra apakšizvēlne
            switch (pos) {
                case 0:
                    if (option[2, 0] == "Window Size: 1x") {
                        option[2, 0] = "Window Size: 2x";
                        window_set_size(1024, 768);
                    } else if (option[2, 0] == "Window Size: 2x") {
                        option[2, 0] = "Window Size: 3x";
                        window_set_size(1536, 1024);
                    } else if (option[2, 0] == "Window Size: 3x") {
                        option[2, 0] = "Window Size: 1x";
                        window_set_size(864, 648);
                    }
                    break;
                case 1:
                    global.fullscreen_enabled = !global.fullscreen_enabled;
                    window_set_fullscreen(global.fullscreen_enabled);
                    break;
                case 2: menu_level = 1; break; // Atpakaļ uz iestatījumiem
            }
            break;

        case 3: // Vadības apakšizvēlne
            if (pos == 6) menu_level = 1; // Atpakaļ uz iestatījumiem
            break;

        case 4: // Mērķa apakšizvēlne
            if (pos == 1) menu_level = 1; // Atpakaļ uz iestatījumiem
            break;
    }

    if _sml != menu_level { pos = 0; } // Atiestatīt pozīciju, mainot izvēlni
    op_length = array_length(option[menu_level]); // Atjaunināt opciju garumu
}

if (pos != last_selected) {
        audio_play_sound(snd_select, 1, false);
        last_selected = pos;
}